vbs-Script funktioniert nicht

[hajo]

Hallo,
folgendes Script bekomme ich nicht zum Laufen.
Hilft jemand?

'==========================================================================
'
' VBScript Source File
'
' NAME: MKSHOT.VBS
'
' AUTHOR: Thorsten Eggeling
' DATE : 01.2001
'
' COMMENT: Screenshot-Demo
'
' nötige Anpassungen: myPath: Ausgabepfad
' Delay in Millisekunde
' GetActiveWindow oder GetFullScreen aktivieren
' CreateFilename: Dateinamen erzeugen
'
'
'==========================================================================
Option Explicit
MsgBox("Bitte dieses Script vor dem Start erst anpassen! Script wird beendet.")
Wscript.Quit



'Deklarationen

'WScript.Quit

Dim myFile
Dim myPath
Dim myClip
Dim WshShell
myPath="H:\temp1"
'Objektreferenzen
set myClip=CreateObject("pcwClip.pcwClip")
Set WshShell = WScript.CreateObject("WScript.Shell")
'Dateinamen erzeugen

myFile=CreateFileName()

With myClip
.BmpFileName=myPath & myFile & ".bmp"
.Delay=1000
'.Notify=True
.GetActiveWindow
'.GetFullScreen
WshShell.Popup "Fertig",1
End With

WshShell.Run myPath & myFile & ".bmp"

Set myClip=nothing
Set WshShell=nothing

Function CreateFileName ()
'
Dim a(5)
Dim NewName
Dim i
a(0)=Day(now)
a(1)=Month(Now)
a(2)=Year(Now)
a(3)=Hour(Now)
a(4)=Minute(Now)
a(5)=Second(Now)
For i = 0 to 5
If Len(a(i))=1 Then a(i)="0" & (a(i))
NewName=NewName & a(i)
Next
CreateFileName="NewName"
End Function

[hajo]

Hallo,

wegen der vielen hits gebe ich hier meine Lösung bekannt:

'==========================================================================
'
' VBScript Source File
'
' NAME: MKSHOT.VBS
'
' AUTHOR: Thorsten Eggeling
' DATE : 01.2001
' geändert durch hajo am 15.07.2012
'
' COMMENT: Screenshot-Demo
'
' nötige Anpassungen: myPath: Ausgabepfad
' Delay in Millisekunde
' GetActiveWindow oder GetFullScreen aktivieren
' CreateFilename: Dateinamen erzeugen
'
'
'==========================================================================
Option Explicit
' Option Explicit bewirkt, dass bereits beim Kompilieren des Programms
' alle Variablen auf eine Deklaration überprüft werden.
' Tippfehler im Code werden gnadenlos reklamiert. Es kann also nicht passieren,
' dass ein Programm auf Grund nicht deklarierter Variablen nicht funktioniert.

'Deklarationen
'WScript.Quit

Dim myFile
Dim myPath
Dim myClip
Dim WshShell
myPath="H:\temp1\ScreenShots\"

'Objektreferenzen
set myClip=CreateObject("pcwClip.pcwClip")
' PCWCLIP.DLL ermöglicht den Zugriff auf die Windows-Zwischenablage.
' Damit ist es möglich, den ClipBoard-Inhalt in einer TXT- oder BMP-Datei zu speichern
' und aus diesen wieder auszulesen.
' Zusätzlich können damit Screenshots erstellt und gleich als BMP-Datei auf der Festplatte abgelegt werden.
' pcwClip.dll ist erforderlich zur Ausführung des Scripts 'mkShot.vbs'
' 1. pcwClip.dll --> c:\WINDOWS\system32
' 2. zur Aktivierung im DOS-Fenster eingeben:
' c:\WINDOWS\system32\regsvr32 h:\Tools\vbs-scripte\pcwClip.dll

Set WshShell = WScript.CreateObject("WScript.Shell")

'Dateinamen erzeugen
myFile=CreateFileName()

With myClip
.BmpFileName=myPath & myFile & ".bmp"
.Delay=300
'.Notify=True
.GetActiveWindow 'mit Verknüpfung + Tastaturkürzel aufrufen,
'sonst verliert das akt. Fenster die Eigenschaft 'active'.
'
'.GetFullScreen
WshShell.Popup "Fertig",1
End With

WshShell.Run myPath & myFile & ".bmp"

Set myClip=nothing
Set WshShell=nothing

Function CreateFileName ()
Dim a(6)
Dim MKShot
Dim i
a(1)=Day(now)
a(2)=Month(Now)
a(3)=Year(Now) & "_"
a(4)=Hour(Now)
a(5)=Minute(Now)
a(6)=Second(Now)
For i = 1 to 6
If Len(a(i))=1 Then a(i)="0" & (a(i))
MKShot=MKShot & a(i)
Next
CreateFilename = "MKSHOT_" & MKShot
End Function