Excel 2010 Daten und Filter in 2 Reitern

[Stefan1967]

Hallo zusammen


Meine Frage ist folgende:

Wenn ich den Filter von Excel einsetzen will, dann muss ich den meines Wissens überhalb der Tabelle einfügen.


Gibt es eine möglickeit Tabelle und Filter so zu trennen, dass die Daten für den Filter in Reiter 1 sind und das "Fenster" des Filters in Reiter 2?
Ich möchte das aus Optikgründen getrennt halten.

Mit meinen Möglichkeiten habe ich mal hin und her probiert, jedoch leider keine Lösung gefunden.

Danke für die Hilfe

[Urs2]

Hallo Stefan

- mit Autofilter kann Excel das nicht.
- mit Copy/Paste von Hand wäre es schon möglich
- automatisch kann das nur ein Auto-Makro

Kopiere diesen Code komplett im VB-Editor in das Verzeichnis des Blattes, wo das Filtrat hinkopiert werden soll.
In Excel2003 Rechtsclick auf den Blatt-Reiter und dann "Code anzeigen"

Private Sub Worksheet_Activate()
    'startet jedesmal automatisch, wenn das Tabellenblatt2 gewählt wird
                    
                    'verhindert Bildschirmflackern
    Application.ScreenUpdating = False
                    'schaltet sich selbst aus...
                    '...beim hin und hergehen zwischen den Blättern, würde es sich sonst immer selbst auslösen...
    Application.EnableEvents = False

    With Sheets("Tabelle1")
                'schaut ob AutoFilter gesetzt ist... (aber nicht ob auch wirklich gefiltert wurde !)
        If .AutoFilterMode Then
                'löscht schon vorhandenes Filtrat >> Grösse muss mindestens der ungefilterten Tabelle entsprechen
            Sheets("Tabelle2").Range("B4:K100").ClearContents
                '...dann wird Filtrat in das andere Blatt kopiert (oder wenn nicht gefiltert wurde, die ganze Tabelle)
            .AutoFilter.Range.Copy Sheets("Tabelle2").Range("B4")
        End If
    End With
    
    Sheets("Tabelle2").Select
                    'schaltet sich selbst wieder ein und...
    Application.EnableEvents = True
                    '... auch die Bildschirm-Erneuerung
    Application.ScreenUpdating = True

End Sub

Alle roten Angaben an Deine Mappe anpassen >>
- Tabellenblatt1 ist das Blatt mit dem Filter
-Tabellenblatt2 ist das Blatt wo das Filtrat hin soll

(den im Blatt gesetzten Filter findet das Makro selbst)

- B4 ist der obere linke Rand, wo das Filtrat hin soll
- B4:K100 ist die max Grösse des Filtrats (= ganze Tabelle)

Das Makro startet automatisch wenn Tabellenblatt2 gewählt wird.
Wenn Auto-Filter drin, wird kopiert (auch wenn kein Filter gesetzt ist)

Gruss Urs